Microsoft Access 掲示板

フォーム [F_4_1　JANコード検索画面] のレコードソースのテーブルはなんでしょうか。

バーコードリーダーを使って　B_1　在庫品マスター　を印刷したものを読み込むつもりなので、何にも関連付けていません。

DoCmd.FindRecord は名前の通り該当するレコードを検索するものです。
フォームのレコードソースに何も設定されていない、つまり、レコードがないということ、ないものを検索することはできません。

フォーム [F_4_1　JANコード検索画面] で、どこから何を検索するつもりなんですか。

テーブル　B_1　在庫品マスター　をレコードソースにしているJANコード　フォーム　F_1　在庫品マスター　入庫の登録画面　の　JANコード　を検索したいのですが・・・。

整理すると、下記のようなことでしょうか。

フォーム[F_1　在庫品マスター　入庫の登録画面]
  レコードソース　[B_1　在庫品マスター]

このフォーム上のコマンドボタン [検索画面を開く]
これをクリックすると、[F_4_1　JANコード検索画面]
が開く。

フォーム[F_4_1　JANコード検索画面]
  テキストボックス [JANコード検索]
  コマンドボタン　[JANコードで検索する]

[JANコード検索] にJANコードを入力する。
あるいは、バーコードリーダから読み込んで入力される。

[JANコードで検索する]をクリックすると、

[F_1　在庫品マスター　入庫の登録画面]で、
入力したJANコードと一致するレコードが検索されて表示される。

上記であっているなら、下記のコードを試してみてください。

Private Sub JANコードで検索する_Click()
    Forms![F_1　在庫品マスター　入庫の登録画面].SetFocus
    Forms![F_1　在庫品マスター　入庫の登録画面]!JANコード.SetFocus
    DoCmd.FindRecord Me.JANコード検索, acEntire
    Docmd.Close acForm, Me.Name
End Sub

FindRecord はアクティブなフォームのフォーカスのあるコントロールが対象ですので、
フォームにSetFocusしてから、コントロールにSetFocusする必要があります。

検索できました。ありがとうございます！！

テーブル　B_1　在庫品マスター JANコード　に登録されていないコード（削除されてしまった）や　未登録の時　に　
未登録のコードを入力しました。もう一度入力コードを確認してください。
と、エラーメッセージを出したいのですが・・・。どのように付け加えたら良いのでしょうか？

検索（FindRecord ）した結果、JANコード と JANコード検索 が一致していなかったら、該当の JANコード が見つからなかったということなりますので、それを利用すればいいでしょう。

Private Sub JANコードで検索する_Click()
    Forms![F_1　在庫品マスター　入庫の登録画面].SetFocus
    Forms![F_1　在庫品マスター　入庫の登録画面]!JANコード.SetFocus
    DoCmd.FindRecord Me.JANコード検索, acEntire
    If Me.JANコード検索 = Forms![F_1　在庫品マスター　入庫の登録画面]!JANコード Then
        Docmd.Close acForm, Me.Name
    Else
        MsgBox "未登録のコードを入力しました。もう一度入力コードを確認してください。"
        Me.SetFocus
        Me.JANコード検索.SetFocus
    End If
End Sub

御世話になります。
上記に加えて、
テキストボックス　JANコード検索 　が　空　のままで間違って　JANコードで検索するボタン　を押してしまった場合　
JANコード検索　に値が入力されていません。JANコードを入力してください。と表示させたい時はどうのようにしたらよいのでしょうか？

クリック時のプロシージャの冒頭に下記のコードを挿入してください。

Private Sub JANコードで検索する_Click()
    If IsNull(Me.JANコード検索) Then
        MsgBox "JANコード検索　に値が入力されていません。JANコードを入力してください。"
        Exit Sub
    End If

    '以下、略

End Sub

テーブル　B1＿在庫品マスター　の　フィールド　JANコード　のデータ型がテキスト型だからではないでしょうか？

本来、バーコードのデータ型は数値型とデータ型のどちらを使うべきなのでしょうか？
何もわからないので　住所入力支援のカスタマバーコードがテキスト型なのでテキスト型にしていますが・・・？

ありがとうございます。
JANコード　以外にも　自社コード　での商品検索がありますので参考にして下記のように記述したところ
メインフォームでのレコードの移動はできているのですが
  MsgBox "未登録のコードを入力しました。もう一度自社コードを確認してください。"　が表示されてしまいます。
どこが間違っているのでしょうか？

Private Sub Btn　自社コードで検索する_Click()

       If Nz(Me.自社コード検索, "") = "" Then
        MsgBox "自社コード入力欄　に値が入力されていません。自社コードを入力してください。"
        Me.SetFocus
        Me.自社コード検索.SetFocus
        Exit Sub
    End If

    Forms![C15＿入出庫履歴＿メイン].SetFocus
    Forms![C15＿入出庫履歴＿メイン]!自社コード.SetFocus
    DoCmd.FindRecord Me.自社コード検索, acEntire

    If Me.自社コード検索 = Forms![C15＿入出庫履歴＿メイン]!自社コード Then
    DoCmd.Close acForm, Me.Name
    Else
        MsgBox "未登録のコードを入力しました。もう一度自社コードを確認してください。"
        Me.SetFocus
        Me.自社コード検索.SetFocus
    End If

End Sub

コードを見る限りは問題なさそうです。
実物をみないと原因の特定は難しそうです。

DoCmd.FindRecord はフォーカス移動させる必要があったり扱いが面倒なので、
別案を提案しておきます。

Private Sub Btn　自社コードで検索する_Click()

    If Nz(Me.自社コード検索, "") = "" Then
        MsgBox "自社コード入力欄　に値が入力されていません。自社コードを入力してください。"
        Me.SetFocus
        Me.自社コード検索.SetFocus
        Exit Sub
    End If

    With Forms![C15＿入出庫履歴＿メイン].Recordset
        .FindFirst "自社コード=" & Me.自社コード検索
        If .NoMatch Then
            DoCmd.Close acForm, Me.Name
        Else
            MsgBox "未登録のコードを入力しました。もう一度自社コードを確認してください。"
            Me.自社コード検索.SetFocus
        End If
    End With
End Sub

自社コード フィールドのデータ型が数値型の場合です。
テキスト型の場合は、下記のように ' で囲んでください。

        .FindFirst "自社コード='" & Me.自社コード検索 & "'"