Microsoft Access 掲示板

　正直、ExcelVBAはよくわかりませんが、ググってみました。　
　これは役に立ちませんか？アレンジすれば、いけるかも？

フォーム上のコントロールすべてをForEachステートメントでチェックし、コントロール名が"txt"で始まるもののみ値を空白に... - Yahoo!知恵袋

フォーム上のコントロールすべてをForEachステートメントでチェックし、コントロール名が"txt"で始まるもののみ値を空白にするカードになります。 "Combo*"も空白にしたいのですがどこに接続すれは良いのでしょうか？ForEachCtrlInMe.ControlsIfCtrl.NameLike"txt*"ThenCtrl.Value=""EndIfNextCtrlEndSub オブジェクト名を使う...

Yahoo!知恵袋

提示のクラスモジュールは、コマンドボタンとテキストボックスを持っています。つまり、コマンドボタンとテキストボックスが関連付けられていることになります。

この関連付けをどのように表現するかを決める必要がありますね。

例えば、
cmdホゲ　と　txtホゲ というように、先頭３文字でコントロールの種類、後の部分で項目名を表現するというような仕様にするとします。
こうすると下記のようなコードでいけます。

Private Sub Form_Load()
    Static co As New Collection    'Class1保存用
    Dim ctl As Control
    For Each ctl In Me.Controls
        If ctl.Name Like "txt*" Then
            co.Add New Class1
            Set co(co.Count).テキスト = ctl
            Set co(co.Count).コマンド = Me.Controls("cmd" & Mid(ctl.Name, 4))
            ctl.OnClick = "[イベント プロシージャ]"
        End If
    Next
End Sub

りんご様　回答ありがとうございました。
hatena様　いつもご教示ありがとうございます。

私の書き方が悪かったとおもいます。
図のように、コマンド51をクリックすると、テキスト０に、有、無が表示されるようにしたいのです。
テキスト0の名前は、txtテキスト0
コマンド51の名前は、cmdコマンド51です。

 cls.Init Me.Controls("cmd" & Mid(ctl.Name, 4)), ctl

色々試したのですが、作動しません。
できましたら、もう一度、コードのご教示をお願いします。
本当に申し訳ありません。

hirotonさんも指摘していますし、上の回答でも、下記のように仕様を提示してます。

この関連付けをどのように表現するかを決める必要がありますね。

例えば、
cmdホゲ　と　txtホゲ というように、先頭３文字でコントロールの種類、後の部分で項目名を表現するというような仕様にするとします。

もし、コントロールの名前を変更せずにということなら、下記のような仕様でどうでしょうか。
（こちらの仕様の方がコードがシンプルになるし、変更に強いコードになります。）

仕様
コマンドボタンのTagプロパティに関連付けるテキストボックス名を設定しておく。

例
コマンドボタン名「コマンド51」
テキストボックス名「テキスト０」
の場合、コマンドボタン「コマンド51」のTagプロパティに「テキスト0」と設定する。

クラスモジュール

Option Explicit

Private WithEvents コマンド As CommandButton
Private WithEvents テキスト As TextBox

'初期化メソッド 引数はコマンドボタン　コマンドボタンのTagにテキストボックス名を設定しておく
Public Sub Init(objコマンド As CommandButton)
    Set コマンド = objコマンド
    Set テキスト = objコマンド.Parent.Controls(objコマンド.Tag)
    コマンド.OnClick = "[イベント プロシージャ]"
End Sub

Private Sub コマンド_Click()
    テキスト.Value = IIf(Nz(テキスト.Value) = "有", "無", "有")
End Sub

'自身を返すプロパティ
Public Property Get Self() As Variant
    Set Self = Me
End Property

フォームモジュール

Private Sub Form_Load()
    Static co As New Collection    'Class1保存用
    Dim ctl As Control
    For Each ctl In Me.Controls
        If ctl.ControlType = acCommandButton And ctl.Tag <> "" Then
            With New Class1
                .Init ctl
                co.Add .Self
            End With
        End If
    Next
End Sub

　汎用性を持たせるのは凄い事だけど、貴方にしか保守出来なくなるのではないかと心配です。
>> 5
　AccessVBAで画像を作りたいのであれば、『テキストボックス配置、ボタン配置、クリック時イベント:[イベントプロシージャ]』、ここまでノーコードじゃダメなの？
　

hiroton様　回答ありがとうございました。
りんご様　仰る通りですね。ちょっと事情がありまして、質問しました。
hatena様　いつも素晴らしいコードありがとうございます。Tagプロパティは初めて知りました。

返信が遅れて申し訳ありません。
本当にありがとうございました。