Microsoft Access 掲示板

サブフォームを単票フォームにするのならばタブの選択に合わせてレコードが移動できるようにすればいいですね
それと、親フォームのレコード移動時にサブフォームのレコード数に合わせてタブの表示/非表示を切り替えればよさそうです

新たに作るサブフォームを[部署データ]とします
タブコントロール[所属部署タブ]を設置します
[所属部署タブ]にページコントロールを[ページ0]～[ページ3]まで設置します

Private Sub Form_Current()
    Const max部署 = 3
    Dim cnt部署 As Long
    Dim i As Long

    cnt部署 = Me!部署データ.Form.Recordset.RecordCount
    cnt部署 = IIf(cnt部署 > max部署, max部署, cnt部署)

    me!所属部署タブ = 0

    For i = 1 To cnt部署 - 1
        Me("ページ" & i).Visible = True
    Next
    
    For i = cnt部署 To max部署
        Me("ページ" & i).Visible = False
    Next
End Sub

Private Sub 所属部署タブ_Change()
    Me!部署データ.Form.Recordset.Move 所属部署タブ - (Me!部署データ.Form.CurrentRecord - 1)
End Sub

コード訂正

Private Sub Form_Current()
    Const max部署 = 4 '//この行を訂正
    Dim cnt部署 As Long
    Dim i As Long

    cnt部署 = Me!部署データ.Form.Recordset.RecordCount
    cnt部署 = IIf(cnt部署 > max部署, max部署, cnt部署)

    me!所属部署タブ = 0

    For i = 1 To cnt部署 - 1
        Me("ページ" & i).Visible = True
    Next
    
    For i = cnt部署 To max部署 - 1 '//この行を訂正
        Me("ページ" & i).Visible = False
    Next
End Sub

Private Sub 所属部署タブ_Change()
    Me!部署データ.Form.Recordset.Move 所属部署タブ - (Me!部署データ.Form.CurrentRecord - 1)
End Sub

添え字（0～）と数（1～）の対応で処理に間違いがあったので修正しておきます

新規で所属部署を登録する画面

新規登録用の画面自体は[部署データ]フォームですか？
[所属部署タブ]タブに[ページ4]を追加します

Private Sub 所属部署タブ_Change()
    If Me!所属部署タブ = 4 Then
        Me!部署データ.Form.Recordset.AddNew
    Else
        If Me!部署データ.Form.NewRecord Then Me!部署データ.Form.Recordset.MoveFirst
        Me!部署データ.Form.Recordset.Move 所属部署タブ - (Me!部署データ.Form.CurrentRecord - 1)
    End If
End Sub

[ページ4]を選択すると新規登録用のレコードに飛ぶようになります。少し手抜きな部分（新規登録から既存のレコードに移るとちらつくかも）がありますが、動作を確認してみてください

ちなみに、このコードだけだと、実際に新規レコードが追加されてもタブの表示は変わりません。「新規で所属部署が登録されたとき」にページのON/OFFを見直す必要があります。親フォームとサブフォームを行ったり来たりな処理でちょっと大掛かりになるので、続きが必要な場合にいは改めて質問を立てなおしてください（大元の質問は、それはそれで続けているようなので）