Microsoft Access 掲示板

さてこれらについて申請中のレポートに、不備欄を設け申請中のもの未申請のもの(申請日がnull)
として販社連絡レポートに一緒に印刷したいのですがご教示お願いします。

ひとつのレポートに 申請中 のものと 未申請 のものを表示したいということでしょうか。
２つのレポートが同じレイアウトなら、
レコードソースのクエリに、下記の演算フィールドを設けて、

申請中: Not [申請日] Is Null

レポートのグループ化の機能で、このフィールドでグループ化すればいいでしょう。

hatena様早速のお返事ありがとうございます。おっしゃるとおりにしましたが
申請日がないものについて表示されません。
上記の式のなかで
stFilter = "本部 In(" & Mid(stFilter, 2) & ")And ([申請日]=#" & [TXT申請] & "#) )"
を
stFilter = "本部 In(" & Mid(stFilter, 2) & ")And ([申請日]=#" & [TXT申請] & "#) )
OR　本部 In(" & Mid(stFilter, 2) & ")And ([申請日]=" & IS NULL([TXT申請]) & ") )"
なんて素人考えでやってますがうまくいきません。

やりたいことはレポートに中からTXT申請日に記入のある申請日と　申請日の記入がない申請日を
選びたいのですが。宜しくご教示のほどお願いします。

やりたいことはレポートに中からTXT申請日に記入のある申請日と　申請日の記入がない申請日を
選びたいのですが。

stFilter に下記のような条件文が格納されるように考えましょう。

本部 In(1,2) And ([申請日] Is Null Or [申請日]=#2019/04/01#)

上記の意味は、(本部が１か2) かつ (申請日が未入力 または 申請日が2019/04/01)
ということです。() 内が優先順位が高いということを利用します。

ということで、下記でどうでしょう。

stFilter = "本部 In(" & Mid(stFilter, 2) & ") And ([申請日] Is Null Or [申請日]=#" & Me.TXT申請 & "#)"

hatena様有り難うございます。
ご指摘のようにしましたが、抽出条件でデータ型が一致しませんと出ます。
宜敷お願いします。
>>申請中: Not [申請日] Is Null
レポートのグループ化の機能で、このフィールドでグループ化すればいいでしょう。
以上のように対応はしています。

確認ですが、「申請日の記入がない」と「不備のもの」というのはイコールですか。

早々に有り難うございました。
申請日の記入がないものは不備ということでコントロールに
自動的に記入になるようにしています。
今後はこういう形に持って行こうと思ってます。
宜敷お願いします。
Dim stFilter As String
Dim stFilter2 As String
Dim stFilter3 As String
Dim varItm As Variant
Dim varItm2 As Variant
Dim varItm3 As Variant
    With Me.listSupplier
        For Each varItm In .ItemsSelected
            stFilter = stFilter & "," & .ItemData(varItm)
        Next
    End With

    If stFilter = "" Then
        MsgBox "本店を選択してください。"
    Else
        stFilter = "本部 In(" & Mid(stFilter, 2) & ") And ([申請日] Is Null Or [申請日]=#" & Me.TXT申請 & "#)"

        On Error Resume Next
        DoCmd.OpenReport "販社連絡", acViewPreview, , stFilter
         On Error GoTo 0

    End If
DoCmd.Close acForm, "F車庫証明台帳"

End Sub

エラーの原因の特定のために下記の手順でコードを順に実行して試してみてください。

On Error の行はデバッグ中はコメントアウトします。
stFilter の条件式をシンプルなものから少しずつ足していく。
エラーが出た直前に足して条件式が原因と特定できる。
Debug.Print でイミディエイトウィンドにstFilterの内容を出力して
それが条件式として問題ないか確認する。
1.

        stFilter = "本部 In(" & Mid(stFilter, 2) & ")"
        Debug.Print stFilter
        'On Error Resume Next 
        DoCmd.OpenReport "販社連絡", acViewPreview, , stFilter
        'On Error GoTo 0

2.

        stFilter = "本部 In(" & Mid(stFilter, 2) & ") And ([申請日]=#" & [TXT申請] & "#)"
        Debug.Print stFilter
        'On Error Resume Next 
        DoCmd.OpenReport "販社連絡", acViewPreview, , stFilter
        'On Error GoTo 0

3.

        stFilter = "本部 In(" & Mid(stFilter, 2) & ") And ([不備]=true Or [申請日]=#" & [TXT申請] & "#)"
        Debug.Print stFilter
        'On Error Resume Next 
        DoCmd.OpenReport "販社連絡", acViewPreview, , stFilter
        'On Error GoTo 0

お世話になります。
1では全申請日が表示されます。
2ではtxt申請日分だけ表示されます。
3では抽出条件でデータ型が一致しませんと出ます。
宜敷お願いします。

それでは、下記ではどうですか。

stFilter = "本部 In(" & Mid(stFilter, 2) & ") And ([申請日] Is Null Or [申請日]=#" & [TXT申請] & "#)"

お世話になります。
3でお示しされたものと一緒ですね。
抽出条件でデータ型が一致しませんと出ます。
何ででしょうかね。
宜敷お願いします。

クエリーで申請日無しを設け　申請日無し: IIf([不備]=-1,"不備")
stFilter = "本部 In(" & Mid(stFilter, 2) & ") And ([申請日無し] ="不備" Or [申請日]=#" & [TXT申請] & "#)"
としましたが受け付けてくれません。

すみません。修正です。
stFilter = "本部 In(" & Mid(stFilter, 2) & ") And [申請日無し]='" & "不備" & "'or ( [申請日]=#" & [TXT申請] & "#)"
やはり抽出条件でデータ型が一致しませんと出ます。

エラーが出たあと、イミディエイトウィンドウに出力されている条件式をコピーしてここに貼り付けてもらえますか。

あと、エラーだ出た時に、エラーダイアログの[デバッグ]ボタンをクリックしたときに反転表示されるコードはどこですか。

お世話になります。
イミディエイトウィンドウにでるのは次です。
本部 In(2) And ([不備]=true Or [申請日]=#2019/04/10#)
デバッグは次です
オートフォントサイズプログラムの8行目です。
Str = Nz(Ctr.Value, "") 'ここでエラーが出る場合は、Str = Nz(Ctr.Value,"")
ちなみに当該レポートでオートフォントサイズを使わなければうまくいくようです。
オートフォントサイズプログラムここでも重宝しています。
こういう調べ方もあるんですね。勉強になります。

エラーがでるのはそこでしたか。先にそれを確認すべきでした。

stFilter = "・・・・" の部分はまったく関係ないですね。

Str = Nz(Ctr.Value,"")
か原因というのは特定できましたが、なぜそうなるかはわからないですね。
コントロールの値が Null だとしても、Nz関数で "" に変換しているだけなので、エラーになるはずがないのてすが。

その前後１０行分のコードを張り付けてもらえますか。

お世話になります。
AutoFontSizeには大変重宝しており感謝申し上げます。
ところで下記項目を縮小で対応しており
この中で出来日を縮小から外せばクレームはないようです。
当面出来日は縮小から外しても支障はありませんので
外して対応しようかと思います。

Private Sub 詳細_Format(Cancel As Integer, FormatCount As Integer)
AutoFontSize Me.支店名, 10
AutoFontSize Me.販社本部, 10
AutoFontSize Me.備考, 10
AutoFontSize Me.申請者, 10
AutoFontSize Me.支店名, 10
AutoFontSize Me.登録予定日, 10
AutoFontSize Me.出来日, 10
AutoFontSize Me.管轄署, 10
End Sub

出来日は申請日と下記のように関連していますので、このあたりに
関係しているのかなと素人考えではありますが。

でもご教示頂いたもので充分でございますので感謝申し上げます。

Public Function 許可日(申請日 As Date) As Date
    Dim 営業日 As Long
    許可日 = 申請日
    Do
        許可日 = 許可日 + 1
        Select Case Weekday(許可日)
        Case vbMonday To vbFriday
            If IsNull(DLookup("祝日名", "T_祝日", "日付=#" & 許可日 & "#")) Then
                営業日 = 営業日 + 1
            End If
        End Select
    Loop Until 営業日 = 2
End Function

クエリーで　出来日:許可日（[申請日]）

活用させて頂いているAutoFontSizeプログラム
Public Sub AutoFontSize(Ctr As Control, IniFontSize As Integer)
    Const MinFontSize = 4 '最小のフォントサイズ
    Const d = 53 'うまく収まらずに改行されてしまう場合はここの数値を増やす
    Dim rpt As Report, Str As String, W As Long
    Dim arStr, i As Integer, H As Long
    Set rpt = CodeContextObject
With rpt
    If Ctr.ControlType = acTextBox Then
      Str = Nz(Ctr.Value, "") 'ここでエラーが出る場合は、Str = Nz(Ctr.Value,"")
    ElseIf Ctr.ControlType = acLabel Then
        Str = Ctr.Caption
    Else
        Exit Sub
    End If
    If Str = "" Then Exit Sub
    .FontName = Ctr.FontName

Function 許可日 が原因の可能性があります。
下記ように変更してください。

Public Function 許可日(申請日 As Variant) As Variant
    Dim 営業日 As Long
    許可日 = 申請日
    If IsNull(許可日) Then Exit Function 
    Do
        許可日 = 許可日 + 1
        Select Case Weekday(許可日)
        Case vbMonday To vbFriday
            If IsNull(DLookup("祝日名", "T_祝日", "日付=#" & 許可日 & "#")) Then
                営業日 = 営業日 + 1
            End If
        End Select
    Loop Until 営業日 = 2
End Function

このたびはお時間をとらせて申し訳ありませんでした。
おかげさまで完璧でございます。
大変有り難うございました。