Microsoft Access 掲示板

sk様
追加のコードについては、投稿時に端折っただけです。

ご提示の1～5の選択肢については3だと思われます。

下記のコードに書き換えて実行してみました。
それでも同じく残業管理ID 95の残業区分が4にならずに2のままでした。
他の残業区分IDは残業区分が3になっています。

    Dim cn As New ADODB.Connection
    Dim rs As New ADODB.Recordset

    Set cn = CurrentProject.Connection
    
    rs.CursorLocation = adUseClient
    rs.Open "tbl残業管理", cn, adOpenKeyset, adLockOptimistic


    rs.Sort = "日付 ASC, 担当者ID ASC, 残業区分 ASC"
    rs.MoveFirst
    
    
    Do Until rs.EOF
    
        If rs!残業区分 = 1 Then
        
            If DCount("休日", "tbl休日", "休日 = #" & rs!日付 & "#") > 0 Then
            
                rs!残業区分 = 3
                rs.Update
                
            End If

    
        ElseIf rs!残業区分 = 2 Then
        
            If DCount("休日", "tbl休日", "休日 = #" & rs!日付 & "#") > 0 Then
            
                rs!残業区分 = 4
                rs.Update
            
            End If

        End If
        
        rs.MoveNext
          
    Loop


    rs.Sort = ""

    rs.Close: Set rs = Nothing
    cn.Close: Set cn = Nothing

ならば考えられる原因は 1 つだけです。

rs.Sort = "日付 ASC, 担当者ID ASC, 残業区分 ASC"

rs!残業区分 = 3

[残業管理ID]の値が 130 であるレコードの[残業区分]の値に 3 を代入（ 1 から 3 に変更）した瞬間に、そのレコードが 2 番目から 3 番目のレコードに、[残業管理ID]の値が 95 である（[残業区分]の値が 2 である）レコードが 3 番目から 2 番目のレコードになった（レコードセット内での絶対位置が入れ替わった）からです。

【 3 を代入する直前の状態】

【 3 を代入した直後の状態】

順番が入れ替わってもその時点でのカレントレコードは[残業管理ID]の値が 130 であるレコードのままなので、その後 MoveNext メソッドを呼び出せばその次（ 4 番目）のレコードは[残業管理ID]の値が 85 であるレコードとなります。

回避手段としては、Sort プロパティを使用せず Open メソッドの呼び出し時に「 ORDER BY 句付きの SELECT 文」を渡すことが挙げられます。

rs.Open "SELECT * FROM [tbl残業管理] ORDER BY [日付] ASC, [担当者ID] ASC, [残業区分] ASC", cn, adOpenKeyset, adLockOptimistic