Microsoft Access 掲示板

ファイル選択ダイアログで、ファイルを選択して、結果からファイル名を取り除くぐらいしかないような気がします。

hatenaさん、ご回答ありがとうございます。
ユーザーの要望が強い場合は、その方法を提案したいと思います。

どうしてもやるとするなら自前でオリジナルのフォームを作る感じですかねぇ

https://www.google.com/search?q=ACCESS+treeview

フォルダを追いかけるツリービューとフォルダを選択（ツリービュー上のアイテムをクリック）したときにそのフォルダ内のファイル一覧を表示するリストボックスを組み合わせるとかで実現できると思います

リンクつけようとしたらなんか掲示板に怒られてしまいました。URLコピペしてください

hirotonさん、ご回答ありがとうございます。参考にさせていただきます。

面白そうなネタだったのでちょっとやってみました

「fFolderPicker」フォームを作成します
ActiveXコントロールから
・「Microsoft TreeView Control, version 6.0」：TreeView
・「Microsoft Forms 2.0 TextBox」：TextBox
を配置します
「TextBox」はWordWrapプロパティを「いいえ」にします

'//標準モジュール：MyFolderPicker
Option Compare Database
Option Explicit

Const defaultPath = "C:"
Public returnString As String

Function folderPicker(Optional folderPath As String)

    If folderPath = "" Or Dir(folderPath, vbDirectory) = "" Then folderPath = defaultPath
    
    returnString = ""
    DoCmd.OpenForm "fFolderPicker", , , , , acDialog, folderPath
    folderPicker = returnString

End Function

'//フォーム：fFolderPicker
Option Compare Database
Option Explicit

Dim fso As Object

Private Sub Form_Close()
    Set fso = Nothing
    MyFolderPicker.returnString = TreeView.SelectedItem.Key
End Sub

Private Sub Form_Load()
    Dim folderPath As String
    Dim folderName As String

    folderPath = OpenArgs
    folderName = Mid(OpenArgs, InStrRev(OpenArgs, "\") + 1)

    Set fso = CreateObject("Scripting.FileSystemObject")
    TreeView.Nodes.Add , , folderPath, folderName
    TreeView_NodeClick TreeView.Nodes(1)
End Sub

Private Sub TreeView_NodeClick(ByVal Node As Object)
    Dim files As String
    Dim file As Object
    For Each file In fso.GetFolder(Node.Key).files
        files = files & file.Name & vbCrLf
    Next
    Me.TextBox.Value = files

    If Node.Tag = "Done" Then Exit Sub

    Dim folder As Object
    For Each folder In fso.GetFolder(Node.Key).SubFolders
        TreeView.Nodes.Add Node.Key, tvwChild, folder.path, folder.Name
    Next

    Node.Tag = "Done"
    Node.Expanded = True
End Sub

手を抜けそうなところは抜きつつ、ですが、このあと、ダイアログとしての体裁を整えるのにさらに苦労することはまた別の話

hirotonさん
ユーザーの要望が強い場合は、実装させていただきます。
ご回答ありがとうございました！