Microsoft Access 掲示板

Len 関数
その文字に何バイト使うか？というのは文字コードに依存します。（LenB関数の埒外）

String Data Type (Visual Basic)
VBAで文字を扱おうとすると基本、Unicodeで扱われます。Unicodeは半角、全角関係なく1文字を2バイトで表現する文字コードです。

半角カナ
いろいろあって、濁音や半濁音を表すときは2文字使うというのが現在です。

以上のことから質問の、

このページの下の「新しいトピックを作る」ボタンをクリックして質問を入力してください。あるいは下記のリンクをクリックしてください。

の例では4文字×2バイト増えた数字が表示されるのです。

半角1文字を１、全角1文字を２とカウントするためには、そう表現する文字コードに変換してLenB()を使う必要があります。最初のリンク先にある通り

LenB(StrConv(str, vbFromUnicode))

のような処理をさせます。

下記コードで半角化＆文字数を表示することができました!
ありがとうございました。

Private Sub btn半角化_Click()
    Me.Refresh
    txt変更テキスト = StrConv([元テキスト], 8)
    txt変更テキスト長さ = LenB(StrConv([変更テキスト], vbFromUnicode))
    Me.Refresh
End Sub

次の質問なのですが、現在ボタンを2回押さないと反映できません。
（それを解消できるかと思って「Me.Refresh」を2回入れているのですが・・だめでした）
1回で反映できる方法はありますでしょうか。

もう１つの質問を記載させていただきます。

現在以下のように、[テキスト]の文章を20バイトで区切ってテキストボックスで３つに分けるという処理をしています。

Private Sub btn項目用_Click()
Const COUNT As Long = 20
    Me.Refresh
        txt項目1 = StrConv(LeftB(StrConv([テキスト], vbFromUnicode), COUNT), vbUnicode)
        txt項目2 = StrConv(MidB(StrConv([テキスト], vbFromUnicode), COUNT + 1, COUNT), vbUnicode)
        txt項目3 = StrConv(MidB(StrConv([テキスト], vbFromUnicode), COUNT * 2 + 1, COUNT), vbUnicode)
       
        txt項目1長さ = LenB(StrConv([項目1], vbFromUnicode))
        txt項目2長さ = LenB(StrConv([項目2], vbFromUnicode))
        txt項目3長さ = LenB(StrConv([項目3], vbFromUnicode))

End Sub

このとき、うまく20バイトずつ文章が分かれてくれたらいいのですが
全角と半角が混ざった文章だと、文字化けしたり21バイトになったりします。
20バイト以下で、文字化けせずにうまくわけることはできませんでしょうか。

以上、ご検討いただければ幸いです。宜しくお願い致します。

全角、半角に関しては、いろいろ複雑な事情があります。
とりあえず下記を参照してください。

半角１桁全角２桁で計算するLenB、LeftB関数の代替関数 - hatena chips

VBA Unicode 文字の入力や変換、読み込みについて

Unicode文字（Shift-JISにない文字)、サロゲートぺー文字の扱いはどうするのかまずは決める必要があると思います。

お騒がせしております。
今気づいたのですが、
res = Mid$(S, M, Len(res))
が
res = Mid$(S, LenAnsiB(M), Len(res))
でしょうか。。
あとで試してみます。

とりあえずUnicodeのことは忘れて、次の例を考えます。

この場合、たとえばMidh(str, a, b)のような関数を作ったとしてMidh("あｲうｴお", 5, 3)としたとき、「う」はどう扱ったらいいでしょうか？

半角を1、全角を2とカウントするようなMidのような関数は現実的ではないでしょう
このようなことをする場合は、すべての文字をひとくくりに考える必要があります

半角を含む文字列を処理する関数「splith()」

Function splith(str As String, n As Long) As String()
'//ANSI（半角1バイト、全角2バイト）を利用してnカウント以内で分割した文字列の配列を返す関数
    Dim strBase As String, strAnsi As String, str1 As String, str2 As String, strLeft As String
    Dim sCount As Long
    
    Dim strSplit() As String
    
    strBase = str
    Do Until strBase = ""
        ReDim Preserve strSplit(sCount)
        strAnsi = strConv(strBase, vbFromUnicode)
        
        '//合計nカウント以内だったらそのまま取り出して終わり
        If LenB(strAnsi) <= n Then
            strSplit(sCount) = strBase
            Exit Do
        End If
        
        '//nカウント目の文字をチェックして2バイト文字なら切り捨てる
        str1 = strConv(LeftB(strAnsi, n), vbUnicode)
        str2 = strConv(LeftB(strAnsi, n + 1), vbUnicode)
        If Len(str1) = Len(str2) Then
            '//2バイト文字から1バイト取り出したら文字数は1（文字は化けるが文字数は1）
            '//余分に1バイト取り出しても正常な文字として文字数は1で、全体の文字数は変わらない
            '//nカウント目の文字が2バイト文字の前半1バイトだったので1バイト減らす
            strLeft = strConv(LeftB(strAnsi, n - 1), vbUnicode)
        Else
            '//余分に1バイト取り出して文字数が変わったらnカウントでちょうど文字の区切りだった
            strLeft = str1
        End If
        
        '//取り出した文字を配列に保存
        strSplit(sCount) = strLeft

        '//取り出した文字分だけ元の文字を取り除く
        strBase = Mid(strBase, Len(strLeft) + 1)

        '//配列の次の要素の準備
        sCount = sCount + 1
    Loop

    splith = strSplit()
End Function

テストコード

Private Sub コマンド0_Click()
Dim strBase As String
Dim strSplit() As String
Dim sCount As Long

strBase = Me!テキスト

If strBase = "" Then Exit Sub

If strBase <> strConv(strConv(strBase, vbFromUnicode), vbUnicode) Then
    MsgBox "非対応の文字が見つかりました。処理を中断します"
    Exit Sub
End If

strBase = strConv(strBase, vbNarrow)
strSplit() = splith(strBase, 20)

For sCount = 0 To UBound(strSplit)
    Debug.Print strSplit(sCount)
Next
End Sub

出力結果

このﾍﾟｰｼﾞの下の｢新し
いﾄﾋﾟｯｸを作る｣ﾎﾞﾀﾝを
ｸﾘｯｸして質問を入力し
てください｡あるいは
下記のﾘﾝｸをｸﾘｯｸして
ください｡

更に初心者の質問で申し訳ありません。
    Debug.Print strSplit(sCount)
の部分についてですが、テキストボックスに1個ずつ格納していきたいと思っています。

テキストボックス名　txtB & scount + 1 として

txtB & sCount + 1 = strSplit(sCount)

というのは、不可能のようですね。。
変数名のカウントアップはどうしたらよいのでしょうか。