Microsoft Access 掲示板

Likeで指定年度を検索して、除く年度を除外すること自体が矛盾してるのでは？
もしかしてやりたいことは、指定年度から除く年月を除外したいのでしょうか？

指定年度検索：テキストボックス名：年度検索
月検索：テキストボックス名：月検索
除く年度検索：テキストボックス名：年度検索２

いろいろな場合が考えられますので、それぞれの場合でどのようにしたいのか具体的に説明してください。

入力一か所

指定年度検索: 入力
月検索: 未入力
除く年度検索： 未入力

指定年度検索: 未入力
月検索: 入力
除く年度検索： 未入力

指定年度検索: 未入力
月検索: 未入力
除く年度検索： 入力

指定年度検索: 入力
月検索: 入力
除く年度検索： 未入力

入力二か所

指定年度検索: 入力
月検索: 入力
除く年度検索： 未入力

指定年度検索: 未入力
月検索: 入力
除く年度検索： 入力

指定年度検索: 入力
月検索: 未入力
除く年度検索： 入力
※これは条件として矛盾

すべて入力

指定年度検索: 入力
月検索: 入力
除く年度検索： 入力
※これは条件として矛盾

このすべてに対応しようとするとクエリではかなり式が複雑になりメンテナンス性が悪いです。
VBAでFilterをかける方法の方がシンプルにできますが、VBAの使用は可能ですか。

レポートのレコードソースには、"年度登録"テーブルを設定します。

コマンドボタン「プレビュー」を配置します。このボタンのクリック時のイベントプロシージャを下記のように記述します。

Private Sub プレビュー_Click()
    Dim strFilter As String
    
    If Not IsNull(Me.年度検索) And Not IsNull(Me.年度検索２) Then
        MsgBox "[指定年度]と[除く年度]を両方入力することはできません！"
        Exit Sub
    End If
    
    If Not IsNull(Me.年度検索) Then
        strFilter = strFilter & " AND 年度=" & Me.年度検索
    End If
    
    If Not IsNull(Me.月検索) Then
        strFilter = strFilter & " AND 月=" & Me.月検索
    End If
    
    If Not IsNull(Me.年度検索２) Then
        strFilter = strFilter & " AND 年度<>" & Me.年度検索２
    End If
    
    strFilter = Mid(strFilter, 6) '先頭の" AND"を削除
    
    
    If DCount("*", "年度登録", strFilter) = 0 Then
        MsgBox "該当するレコードはありません。"
    Else
        DoCmd.OpenReport "レポート名", acViewPreview, , strFilter
    End If

End Sub

OpenReportの第4引数に抽出条件を設定できます。