Microsoft Access 掲示板

Acc2016なら条件付き書式4件以上でも追加できるはずです。（最大何件かまでは把握してませんが。）
3件まではかなり前のバージョンだったと思います。

最初に条件付き書式を削除してから、追加してますか。

実際のコードを提示してください。

ありがとうございます
実際のコードは以下のようになっています

Dim Db      As DAO.Database
Dim Rs      As Recordset
Dim StrSQL  As String
Dim Fmt     As FormatCondition

Private Sub Form_Load()
    Set Db = CurrentDb
    StrSQL = "SELECT DISTINCT 文字色 FROM 項目MT ORDER BY 文字色"
    Set Rs = Db.OpenRecordset(StrSQL, dbOpenSnapshot)
    Me!項目.FormatConditions.Delete　　→ここで削除してるはず
    Do Until Rs.EOF = True
        Set Fmt = Me!項目.FormatConditions.Add(acExpression, acEqual, "[文字色] = " & Rs!文字色)
        Fmt.ForeColor = Rs!文字色　　→　ループ4回目のここでエラーになります
        Rs.MoveNext
    Loop
End Sub

手元にあるフォームで試してみましたが、6件登録してもエラーにはなりませんでした。

テーブルとか作るのは面倒なので、色は配列にしました。

Private Sub Form_Load()
    Dim Fmt As FormatCondition

    Dim Colors
    Colors = Array(vbRed, vbGreen, vbYellow, vbBlue, vbMagenta, vbCyan)
    With Me!名前.FormatConditions
        .Delete
        Dim i As Long
        For i = 0 To UBound(Colors)
           Set Fmt = .Add(acExpression, acEqual, "[ID]=" & i + 1)
           Fmt.ForeColor = Colors(i)
        Next
    End With
End Sub

Access2019ですので、ひょっとしてバージョンで違うのかな。
デザインビューで手作業で条件書式を追加したときは4件以上でも登録できますか。

デザインビューで試してみたところ4件、5件と追加できていました…
正直なところ2016でなぜこのエラーが出るのか分かりません

今日は無理ですが、明日、出先にAccess2013環境があるので試してみます。

文字色がレコードに保存されているならリッチテキスト形式を使うと楽ができるかもしれません

標準モジュールに次の関数を追加する（※）

'R+G*256+B*256*256の値をカラーコード表記に変換する
Function getColorCode_D2H(decimalValue As Long)
    Dim HexString As String
    HexString = Right("000000" & Hex(decimalValue), 6)
    
    '並び順がBGRなので順番を変えてカラーコード表記にする
    getColorCode_D2H = "#" & Right(HexString, 2) & Mid(HexString, 3, 2) & Left(HexString, 2)
End Function

新たにテキストボックスを設置する

コントロールソース: ="<font color=""" & getColorCode_D2H([文字色]) & """>" & [項目] & "</font>"
文字書式：リッチ テキスト形式

このテキストボックスは編集できないので、編集が必要なら元のテキストボックスにぴったり重ね合わせて（前面配置にする）フォーカス取得時にMe!項目.setFocusとかしてあげる必要があります

（※）単純な計算なので関数を使わず直接コントロールソースで計算させることもできます

="<font color=""#" & Right(Hex([文字色]+256),2) & Mid(Hex([文字色]+16777216),4,2) & Mid(Hex([文字色]+16777216),2,2) & """>" & [項目] & "</font>"

いつも各種資料を見させて頂いている中、指導ポイントがスゴｲ。
ここまで適格に指導されているホームページは他にはないと思います。