Microsoft Access 掲示板

複数選択可能なリストボックスを使ったうんぬんってそれなりに高度な内容（だと思っている）ので本題との難易度の差がどこで躓いているのかよくわからんです

Filter プロパティ (Access)

FilterにはWHERE句と同等の文字列を設定する（てきとー）なので

Me![販売実績サブ].Form.Filter = "顧客ID=1 AND 製品コード IN('a','b')"

のようになるようstrFilterを作ってあげれば良いです

下記のような仕様だと仮定した場合のコード例

顧客を選択するコンボボックス
名前 cb顧客
連結しているフィールド 顧客ID（数値型）

Private Sub フィルタ適用ボタン_Click()
    Dim strFilter As String 'フィルタ文字列

    '製品用フィルター生成
    Dim Itm As Variant
    For Each Itm In Me![リスト].ItemsSelected
        strFilter = strFilter & ",'" & Itm & "'"
    Next
    If strFilter = "" Then
        MsgBox "製品をリストから選択してください。"
        Exit Sub
    End If
    strFilter = "製品コード In (" & Mid(strFilter, 2) & ")"
    
    '顧客用フィルター追加
    If Me!cb顧客 <> "" Then
        strFilter = "顧客ID=" & Me!cb顧客 & " AND " & strFilter
    End If
    
    If strFilter <> "" Then
        Me![販売実績サブ].Form.Filter = strFilter
        Me![販売実績サブ].Form.FilterOn = True
    End If

End Sub

hatenaさんありがとうございます！

早速試したのですが、
strFilter = "顧客ID=" & Me!cb顧客 & " AND " strFilter
ここで「構文エラー」になってしまいます・・・泣

hatenaさんありがとうございます。

が、しかし、エラーは出なくなったのですが、
フィルタ適用ボタンを押してもサブフォームになにも出てこなくなってしまいました　泣
（フォームを開いたときはすべてのデータが表示されるのですが、
その後顧客IDを選んで、製品コードを選んで、「フィルタ適用」を押すとなにも表示されなくなってしまいます。）

では、まず、私の回答のコードを参考にして、実際に書いたコードを提示してください。

あと、顧客ID と 製品コード のデータ型も教えてください。（数値型か、テキスト型か）

hatenaさんありがとうございます。

顧客ID：数値型
製品コード：テキスト型

コード提示いたします。

デバッグをしてみたところ、 Itmがemptyになっていることに気が付きました。
サブフォームになにも表示されなくなってしまう件と
なにか関係がありますでしょうか・・・？

‘‘‘Private Sub フィルタ適用ボタン_Click()

    Dim strFilter As Variant 'フィルタ文字列
    Dim trFilter As Variant

    '製品用フィルター生成
    Dim Itm As Variant

    For Each Itm In Me![製品リストbox].ItemsSelected
        strFilter = strFilter & ",'" & Itm & "'"
    Next
    If strFilter = "" Then
        MsgBox "製品をリストから選択してください。"

        Exit Sub

    End If

    strFilter = "製品コード In (" & Mid(strFilter, 2) & ")"

    '顧客用フィルター追加
    If Me!コンボID <> "" Then
            trFilter = "顧客ID=" & Me!コンボID & " AND " & strFilter
    End If

    If strFilter <> "" Then
        Me![販売実績サブ].Form.Filter = strFilter
        Me![販売実績サブ].Form.FilterOn = True
    End If

End Sub‘‘‘

コードに下記のようにデバッグ用のコードを埋め込んでください。

その後、フォームを開いて、リストボックスでリストを複数選択して、フィルタ適用ボタンをクリックします。

次に、Ctrl+G でイミディエイトウィンドウを開いて、そこに出力されているテキストをコピーしてここに貼り付けてもらえますか。

Private Sub フィルタ適用ボタン_Click()

    Dim strFilter As String 'フィルタ文字列

    Debug.print "選択数: " & Me![製品リストbox].ItemsSelected.Count '※デバッグコード

    '製品用フィルター生成
    Dim Itm As Variant
    For Each Itm In Me![製品リストbox].ItemsSelected
        strFilter = strFilter & ",'" & Itm & "'"
    Next

    If strFilter = "" Then
        MsgBox "製品をリストから選択してください。"

        Exit Sub
    End If

    strFilter = "製品コード In (" & Mid(strFilter, 2) & ")"

    Debug.print "strFilter: " & strFilter '※デバッグコード

    '顧客用フィルター追加
    If Me!コンボID <> "" Then
            trFilter = "顧客ID=" & Me!コンボID & " AND " & strFilter
    End If

    If strFilter <> "" Then
        Me![販売実績サブ].Form.Filter = strFilter
        Me![販売実績サブ].Form.FilterOn = True
    End If

    Debug.print "Form.Filter: " & Me![販売実績サブ].Form.Filter '※デバッグコード

End Sub

貼り付けます。

選択数: 4
strFilter: 製品コード In ('0','1','3','5')
Form.Filter: 製品コード In ('0','1','3','5')
選択数: 3
strFilter: 製品コード In ('0','1','3')
Form.Filter: 製品コード In ('0','1','3')
選択数: 3
strFilter: 製品コード In ('0','1','2')
Form.Filter: 製品コード In ('0','1','2')
選択数: 3
strFilter: 製品コード In ('0','1','2')
Form.Filter: 製品コード In ('0','1','2')

For Each Itm In Me![製品リストbox].ItemsSelected

これでItmに入るのはリストのインデックスになってますね。ItemsSelected プロパティ (Access)
（インデックスを入れる変数名にItmを使うのはなんかやだなぁと思ったけどリンク先の例文もvarItmだった・・・）

    '製品用フィルター生成
    Dim listIndex As Variant
    For Each listIndex In Me![製品リストbox].ItemsSelected
        strFilter = strFilter & ",'" & Me![製品リストbox].ItemData(listIndex)  & "'"
    Next

あと

    '顧客用フィルター追加
    If Me!コンボID <> "" Then
'           trFilter = "顧客ID=" & Me!コンボID & " AND " & strFilter  ←コピペミス？'
            strFilter = "顧客ID=" & Me!コンボID & " AND " & strFilter
    End If

VBEのオプション設定のお勧めを徹底解説
VBA触るなら読まないと損するページです。
つまらないミスをなくすためにも変数宣言の強制を。

hirotonさん、サポートありがとうございます。
ItemsSelected はインデックスが入るのでした。あと、コピペミスもしてました。
うしねこさん、hirotonさんの回答を参考に修正してください。

hirotonさん
hatenaさん

理想どおりに動きました！！

まだよく理解できていない部分も多いので、
リンク先をよく見て勉強します。
本当にありがとうございました。