Microsoft Access 掲示板

クエリのSQLを書き換えてからエクスポートするといいでしょう。
エクスポート後にクエリのSQLを元に戻しておきます。
エクスポートが失敗しても、必ず元に戻せるようにエラー処理も追加しておいた方がいいでしょう。
下記のような感じのコードになります。

    Const QueryName = "Q年度別売上集計_Cross_顧客と営業担当別"
    Dim qd As DAO.QueryDef
    Dim strFilter As String
    Dim strSQL As String
    Set qd = CurrentDb.QueryDefs(QueryName)
    strSQL = Replace(qd.SQL, ";", "")
    
    'クエリの抽出条件にフォームのFilterを設定する
    qd.SQL = "SELECT * FROM (" & strSQL & ") WHERE " & Me.Filter & ";"
    
    On Error Resume Next 'エクスポートがエラーになっても以降の行を実行
    'エクセルにエクスポート
    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, QueryName, Filepath & FileName, True
    
    'クエリのSQLを元に戻す
    qd.SQL = strSQL & ";"
    On Error GoTo 0 'エラー処理をを無効にする

hatenaさん　ありがとうございます。
頂いたコードをコピーして実行したところ　”変数が定義されていません”のエラーが出ました。見ると　Set qd = db.QueryDefs(QueryName)　のdb部を示してました。これの変数宣言はどう追記したらいいでしょうか？　すみませんＤＡＯは全然知識ないもので。

その部分を下記に修正してください。

    Set qd = CurrentDb.QueryDefs(QueryName)

元の回答のコードも修正しておきました。

確認してみたら、#1の回答のコードではだめですね。
クロス集計クエリはサブクエリにはできないようです。

いま、修正コードを作成中ですのでしばらくお待ちください。

普通の選択クエリや集計クエリなら#1の回答のコードでOKですが、
クロス集計クエリの場合は、下記のコードを使用してください。

    Const QueryName = "Q年度別売上集計_Cross_顧客と営業担当別"
    Dim strSQL As String  'エクスポート用一時クエリのSQL
    strSQL = "SELECT * FROM " & QueryName
    If Me.Filter <> "" And Me.FilterOn Then
        strSQL = strSQL & " WHERE " & Me.Filter
    End If
    
    Dim db As Database, qd As DAO.QueryDef
    Set db = CurrentDb
    Set qd = db.CreateQueryDef("TempQuery", strSQL & ";") 'エクスポート用一時クエリの作成
     
    On Error Resume Next 'エクスポートがエラーになった場合でも以降の行を実行
    'エクセルにエクスポート
    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, "TempQuery", Filepath & FileName, True
    
    '一時クエリの削除
    db.QueryDefs.Delete "TempQuery"    
    On Error GoTo 0 'エラー処理をを無効にする

hatenaさん　ありがとうございます。
最終で頂いたコードで上手く出来ました。とても自分では解決できる事ではありませんでした。
ＤＡＯも勉強が必用だなと感じました（中々ハードル高いですが）。
毎回対応して頂き感謝です。