Microsoft Access 掲示板

入力用フォームに配置したコマンドボタンでレポートプレビューさせた時にオリジナルの簡単な印刷設定フォーム（名前：Ｆ印刷設定）も一緒に開く様にしてます。

レポートをプレビューした直後に印刷設定フォームも開くということですね。
ならば、Screen.ActiveReport で直前に開いたレポートを取得できますので、それを利用すればどうでしょう。

Ｆ印刷設定のフォームモジュール

Option Compare Database
Option Explicit
Private rptName As String  
    
Private Sub Form_Open(Cancel As Integer)
    On Error Resume next
    rptName = Screen.ActiveReport.Name
    If Err <> 0 Then
        Cancel = True
        MsgBox "レポートが開いていません。"
    End If
End Sub

Private Sub ボタン１_Click()
    If vbOK = MsgBox("直ちに印刷を開始します。", vbOKCancel) Then
        DoCmd.OpenReport rptName, acViewNormal, "", "", acNormal
    Else
        MsgBox "印刷処理を中止します。", vbCritical
        End
    End If
End Sub

Private Sub ボタン2_Click()
    DoCmd.SelectObject acReport, rptName, False
    DoCmd.RunCommand acCmdPrint
End Sub

hatenaさん　ありがとうございます。このコードで上手くいきました。Screen.ActiveReportの事は初めて知りました。
ものすごく初歩的な質問なのですが　Private rptName As String 　はVBA画面の一番上に記述するから参照出来るのですね？（フォーム内の色々な所に）
あともう一つの質問の方の　レポート上に小さい埋め込み画像（イメージ１）の表示有無はどうやって実現可能でしょうか？

ものすごく初歩的な質問なのですが　Private rptName As String 　はVBA画面の一番上に記述するから参照出来るのですね？（フォーム内の色々な所に）

モジュールレベル変数となり、モジュール内のコードならどこからでも参照できる変数になります。他のモジュールからは参照できません。

どの範囲で参照できるかをスコープといいます。「VBA スコープ」のキーワードにWEB検索してみてください。解説ページがいろいろ見つかると思いますので研究してみてください。

レポート上に小さい埋め込み画像があります。この画像を条件により表示／非表示にしたいのです。このレポートは入力フォーム上のボタンでプレビューさせ、フォーム上の画像あり／なしのオプションボタンで条件設定をしようと考えてます。

フォーム上のプレビューボタンでレポートをプレビューするときに、Docmd.OpenReportメソッドの OpenArgs引数でオプショングループの値を渡せばいいでしょう。

下記のような設定と仮定します。

オプショングループ

このオプショングループ内に下記のオプションボタンが２つ配置してある

プレビューボタンクリック時

Private Sub プレビューボタン_Click()
    DoCmd.OpenReport "レポート１", acViewPreview, "", "", acWindowNormal, Me.フレーム1.Value
End Sub

レポートの読み込み時

Private Sub Report_Load()
    If OpenArgs = 1 Then
        Me.イメージ１.Visible = True
    Else
        Me.イメージ１.Visible = False
    End If
End Sub

hatenaさん重ね重ねありがとうございます。「VBA スコープ」少し調べました。記述位置以外にも Private、Publicで範囲が変わってきますね。使いこなすことが出来れば大分コードが集約されそうです。参考になりました。
OpenArgsも初めて知りました。これも重宝しそうです。
大変お世話になりました。