Microsoft Access 掲示板

ファイルを見ました。
フォーム1のレコードソースは「クエリ1」です。
フォーム2のレコードソースは「テーブル2」です。

「フォーム2」のデータを一括で「フォーム2」に追加したいということは、
言い換えれば、「テーブル2」のデータを「クエリ1」（テーブル1と同じもの）に追加するということです。
追加クエリという機能がありますので、それを使えば簡単に一括追加できます。

「テーブル2」から「テーブル1」にデータを追加する追加クエリを作成してください。
一括ボタンのクリック時にその追加クエリを実行するコードを記述すればいいでしょう。
追加クエリを実行後に、フォーム1を再クエリするれば、追加データが表示されます。

hatena 様

ありがとうございます。
追加クエリを使わない方法はないでしょうか？
サンプルは簡素化しておりまして実際は複雑になっており
作り直しができない状態です。
コードではできないのでしょうか？

申し訳ありません。

どのように複雑なのでしょうか。
フォーム2のデータをフォーム1にそのまま追加するだけではないのですか。

データを追加するだけなら、追加クエリが一番簡単です。追加クエリをコードで実行して再クエリです。
コード例

Private Sub コマンド8_Click()
    CurrentDb.Execute "追加クエリ"
    Forms![フォーム1].SetFocus
    Forms![フォーム1].Requery
End Sub

追加クエリを作成したくないなら、コードにSQLを直接記述することも可能です。

Private Sub コマンド8_Click()
    CurrentDb.Execute "INSERT INTO テーブル1 SELECT [テーブル２].* FROM テーブル２;"
    Forms![フォーム1].SetFocus
    Forms![フォーム1].Requery
End Sub

一応、追加クエリ（SQL）を使わない別案も出しておきます。

Private Sub コマンド8_Click()
    Dim MeRs As DAO.Recordset
    Set MeRs = Me.Recordset
    If MeRs.RecordCount = 0 Then
        MsgBox "データがありません。"
        Exit Sub
    End If
        
    Forms![フォーム1].SetFocus
    Dim TargetRs As DAO.Recordset
    Set TargetRs = Forms![フォーム1].Recordset

    MeRs.MoveFirst
    Do Until MeRs.EOF
        TargetRs.AddNew
        TargetRs!項目 = MeRs!項目
        TargetRs!金額 = MeRs!金額
        TargetRs.Update
        MeRs.MoveNext
    Loop

End Sub

追加クエリの方がシンプルですし、処理も高速です。

hatena　様

ありがとうございます。
３通りとも確認し思っていた通りに動作しました。
追加クエリを使用することに致しました。
お手数をお掛け致しました。
勉強になりました。